Repository navigation
Expand file tree
/
Copy pathsubagent.zig
More file actions
1268 lines (1125 loc) · 49.9 KB
/
Copy pathsubagent.zig
File metadata and controls
1268 lines (1125 loc) · 49.9 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
//! SubagentManager — background task execution via isolated agent instances.
//!
//! Spawns subagents in separate OS threads with restricted tool sets
//! (no message, spawn, delegate — to prevent infinite loops).
//! Task results are routed back to the originating channel/session.
const std = @import("std");
const std_compat = @import("compat");
const Allocator = std.mem.Allocator;
const bus_mod = @import("bus.zig");
const config_mod = @import("config.zig");
const config_types = @import("config_types.zig");
const observability = @import("observability.zig");
const provider_names = @import("provider_names.zig");
const providers = @import("providers/root.zig");
const thread_stacks = @import("thread_stacks.zig");
const log = std.log.scoped(.subagent);
// ── Task types ──────────────────────────────────────────────────
pub const TaskStatus = enum {
running,
completed,
failed,
};
pub const TaskState = struct {
status: TaskStatus,
label: []const u8,
origin_channel: []const u8,
origin_chat_id: []const u8,
origin_account_id: ?[]const u8 = null,
session_key: ?[]const u8 = null,
result: ?[]const u8 = null,
error_msg: ?[]const u8 = null,
notified: bool = false,
started_at: i64,
completed_at: ?i64 = null,
thread: ?std.Thread = null,
};
pub const CompletionNotice = struct {
task_id: u64,
content: []u8,
origin_channel: []u8,
origin_chat_id: []u8,
origin_account_id: ?[]u8 = null,
};
pub const SubagentConfig = struct {
max_iterations: u32 = 15,
max_concurrent: u32 = 4,
};
pub const TaskRunRequest = struct {
task: []const u8,
system_prompt: []const u8,
api_key: ?[]const u8,
default_provider: []const u8,
default_model: ?[]const u8,
temperature: f64,
workspace_dir: []const u8,
allowed_paths: []const []const u8,
http_enabled: bool,
http_allowed_domains: []const []const u8,
http_max_response_size: u32,
http_timeout_secs: u64,
tools_config: config_types.ToolsConfig,
memory_config: config_types.MemoryConfig,
max_tool_iterations: u32,
autonomy: config_types.AutonomyLevel,
workspace_only: bool,
allowed_commands: []const []const u8,
max_actions_per_hour: u32,
require_approval_for_medium_risk: bool,
block_high_risk_commands: bool,
block_medium_risk_commands: bool,
allow_raw_url_chars: bool,
configured_providers: []const config_types.ProviderEntry,
observer: ?observability.Observer = null,
};
pub const TaskRunnerFn = *const fn (allocator: Allocator, request: TaskRunRequest) anyerror![]const u8;
// ── ThreadContext — passed to each spawned thread ────────────────
const ThreadContext = struct {
manager: *SubagentManager,
task_id: u64,
task: []const u8,
label: []const u8,
agent_name: ?[]const u8 = null,
trace_id: ?[32]u8 = null,
};
// ── SubagentManager ─────────────────────────────────────────────
pub const SubagentManager = struct {
allocator: Allocator,
tasks: std.AutoHashMapUnmanaged(u64, *TaskState),
next_id: u64,
mutex: std_compat.sync.Mutex,
config: SubagentConfig,
bus: ?*bus_mod.Bus,
// Context needed for creating providers in subagent threads
api_key: ?[]const u8,
default_provider: []const u8,
default_model: ?[]const u8,
workspace_dir: []const u8,
config_path: []const u8,
allowed_paths: []const []const u8,
agents: []const config_mod.NamedAgentConfig,
autonomy: config_types.AutonomyLevel,
workspace_only: bool,
allowed_commands: []const []const u8,
max_actions_per_hour: u32,
require_approval_for_medium_risk: bool,
block_high_risk_commands: bool,
block_medium_risk_commands: bool,
allow_raw_url_chars: bool,
configured_providers: []const config_types.ProviderEntry,
http_enabled: bool,
http_allowed_domains: []const []const u8,
http_max_response_size: u32,
http_timeout_secs: u64,
tools_config: config_types.ToolsConfig,
memory_config: config_types.MemoryConfig,
observer: ?observability.Observer = null,
task_runner: ?TaskRunnerFn = null,
pub fn init(
allocator: Allocator,
cfg: *const config_mod.Config,
bus: ?*bus_mod.Bus,
subagent_config: SubagentConfig,
) SubagentManager {
return .{
.allocator = allocator,
.tasks = .{},
.next_id = 1,
.mutex = .{},
.config = subagent_config,
.bus = bus,
.api_key = cfg.defaultProviderKey(),
.default_provider = cfg.default_provider,
.default_model = cfg.default_model,
.workspace_dir = cfg.workspace_dir,
.config_path = cfg.config_path,
.allowed_paths = cfg.autonomy.allowed_paths,
.agents = cfg.agents,
.autonomy = cfg.autonomy.level,
.workspace_only = cfg.autonomy.workspace_only,
.allowed_commands = cfg.autonomy.allowed_commands,
.max_actions_per_hour = cfg.autonomy.max_actions_per_hour,
.require_approval_for_medium_risk = cfg.autonomy.require_approval_for_medium_risk,
.block_high_risk_commands = cfg.autonomy.block_high_risk_commands,
.block_medium_risk_commands = cfg.autonomy.block_medium_risk_commands,
.allow_raw_url_chars = cfg.autonomy.allow_raw_url_chars,
.configured_providers = cfg.providers,
.http_enabled = cfg.http_request.enabled,
.http_allowed_domains = cfg.http_request.allowed_domains,
.http_max_response_size = cfg.http_request.max_response_size,
.http_timeout_secs = cfg.http_request.timeout_secs,
.tools_config = cfg.tools,
.memory_config = cfg.memory,
};
}
pub fn deinit(self: *SubagentManager) void {
// Join all running threads and free task states
var it = self.tasks.iterator();
while (it.next()) |entry| {
const state = entry.value_ptr.*;
if (state.thread) |thread| {
thread.join();
}
if (state.result) |r| self.allocator.free(r);
if (state.error_msg) |e| self.allocator.free(e);
self.allocator.free(state.origin_channel);
self.allocator.free(state.origin_chat_id);
if (state.origin_account_id) |aid| self.allocator.free(aid);
if (state.session_key) |sk| self.allocator.free(sk);
self.allocator.free(state.label);
self.allocator.destroy(state);
}
self.tasks.deinit(self.allocator);
}
/// Spawn a background subagent. Returns task_id immediately.
pub fn spawn(
self: *SubagentManager,
task: []const u8,
label: []const u8,
origin_channel: []const u8,
origin_chat_id: []const u8,
origin_account_id: ?[]const u8,
origin_session_key: []const u8,
) !u64 {
return self.spawnWithAgent(task, label, origin_channel, origin_chat_id, origin_account_id, origin_session_key, null);
}
/// Spawn a background subagent using an optional named agent profile.
/// When `agent_name` is set, provider/model/prompt are resolved from `agents.list`.
pub fn spawnWithAgent(
self: *SubagentManager,
task: []const u8,
label: []const u8,
origin_channel: []const u8,
origin_chat_id: []const u8,
origin_account_id: ?[]const u8,
origin_session_key: []const u8,
agent_name: ?[]const u8,
) !u64 {
self.mutex.lock();
defer self.mutex.unlock();
if (agent_name) |name| {
if (self.findAgent(name) == null) return error.UnknownAgent;
}
if (self.getRunningCountLocked() >= self.config.max_concurrent)
return error.TooManyConcurrentSubagents;
const task_id = self.next_id;
self.next_id += 1;
const state = try self.allocator.create(TaskState);
errdefer self.allocator.destroy(state);
const state_label = try self.allocator.dupe(u8, label);
errdefer self.allocator.free(state_label);
const state_origin_channel = try self.allocator.dupe(u8, origin_channel);
errdefer self.allocator.free(state_origin_channel);
const state_origin_chat = try self.allocator.dupe(u8, origin_chat_id);
errdefer self.allocator.free(state_origin_chat);
const state_origin_account = if (origin_account_id) |account_id| try self.allocator.dupe(u8, account_id) else null;
errdefer if (state_origin_account) |account_id| self.allocator.free(account_id);
const state_session = try self.allocator.dupe(u8, origin_session_key);
errdefer self.allocator.free(state_session);
state.* = .{
.status = .running,
.label = state_label,
.origin_channel = state_origin_channel,
.origin_chat_id = state_origin_chat,
.origin_account_id = state_origin_account,
.session_key = state_session,
.started_at = std_compat.time.milliTimestamp(),
};
try self.tasks.put(self.allocator, task_id, state);
errdefer _ = self.tasks.remove(task_id);
const task_copy = try self.allocator.dupe(u8, task);
errdefer self.allocator.free(task_copy);
const label_copy = try self.allocator.dupe(u8, label);
errdefer self.allocator.free(label_copy);
const agent_name_copy = if (agent_name) |name| try self.allocator.dupe(u8, name) else null;
errdefer if (agent_name_copy) |name| self.allocator.free(name);
const trace_id = if (self.observer) |obs| obs.getTraceId() else null;
// Build thread context
const ctx = try self.allocator.create(ThreadContext);
errdefer self.allocator.destroy(ctx);
ctx.* = .{
.manager = self,
.task_id = task_id,
.task = task_copy,
.label = label_copy,
.agent_name = agent_name_copy,
.trace_id = trace_id,
};
state.thread = try std.Thread.spawn(.{ .stack_size = thread_stacks.HEAVY_RUNTIME_STACK_SIZE }, subagentThreadFn, .{ctx});
return task_id;
}
fn findAgent(self: *const SubagentManager, name: []const u8) ?config_mod.NamedAgentConfig {
for (self.agents) |agent| {
if (std.mem.eql(u8, agent.name, name)) return agent;
}
return null;
}
pub fn getTaskStatus(self: *SubagentManager, task_id: u64) ?TaskStatus {
self.mutex.lock();
defer self.mutex.unlock();
if (self.tasks.get(task_id)) |state| {
return state.status;
}
return null;
}
pub fn getTaskResult(self: *SubagentManager, task_id: u64) ?[]const u8 {
self.mutex.lock();
defer self.mutex.unlock();
if (self.tasks.get(task_id)) |state| {
return state.result;
}
return null;
}
pub fn getRunningCount(self: *SubagentManager) u32 {
self.mutex.lock();
defer self.mutex.unlock();
return self.getRunningCountLocked();
}
fn getRunningCountLocked(self: *SubagentManager) u32 {
var count: u32 = 0;
var it = self.tasks.iterator();
while (it.next()) |entry| {
if (entry.value_ptr.*.status == .running) count += 1;
}
return count;
}
fn formatTaskCompletionContent(allocator: Allocator, label: []const u8, result: ?[]const u8, err_msg: ?[]const u8) ![]u8 {
return if (result) |r|
try std.fmt.allocPrint(allocator, "[Subagent '{s}' completed]\n{s}", .{ label, r })
else if (err_msg) |e|
try std.fmt.allocPrint(allocator, "[Subagent '{s}' failed]\n{s}", .{ label, e })
else
try std.fmt.allocPrint(allocator, "[Subagent '{s}' finished]", .{label});
}
/// Mark a task as completed or failed. Thread-safe.
fn completeTask(self: *SubagentManager, task_id: u64, result: ?[]const u8, err_msg: ?[]const u8) void {
// Dupe result/error into manager's allocator (source may be arena-backed)
const owned_result = if (result) |r| self.allocator.dupe(u8, r) catch null else null;
const owned_err = if (err_msg) |e| self.allocator.dupe(u8, e) catch null else null;
var label: []const u8 = "subagent";
var origin_channel: []const u8 = "system";
var origin_chat_id: []const u8 = "subagent";
var origin_account_id: ?[]const u8 = null;
{
self.mutex.lock();
defer self.mutex.unlock();
if (self.tasks.get(task_id)) |state| {
state.status = if (owned_err != null) .failed else .completed;
state.result = owned_result;
state.error_msg = owned_err;
state.notified = false;
state.completed_at = std_compat.time.milliTimestamp();
label = state.label;
origin_channel = state.origin_channel;
origin_chat_id = state.origin_chat_id;
origin_account_id = state.origin_account_id;
}
}
const content = formatTaskCompletionContent(self.allocator, label, owned_result, owned_err) catch return;
defer self.allocator.free(content);
// Route result via bus (outside lock)
if (self.bus) |b| {
var out = if (origin_account_id) |account_id|
bus_mod.makeOutboundWithAccount(
self.allocator,
origin_channel,
account_id,
origin_chat_id,
content,
) catch return
else
bus_mod.makeOutbound(
self.allocator,
origin_channel,
origin_chat_id,
content,
) catch return;
b.publishOutbound(out) catch |err| {
out.deinit(self.allocator);
log.err("subagent: failed to publish result to outbound bus: {}", .{err});
};
}
}
pub fn takeCompletionNoticesForSession(
self: *SubagentManager,
allocator: Allocator,
session_key: ?[]const u8,
) ![]CompletionNotice {
return self.takeCompletionNoticesFiltered(allocator, .{ .session_key = session_key });
}
pub fn takeCompletionNoticesForOrigin(
self: *SubagentManager,
allocator: Allocator,
origin_channel: []const u8,
origin_account_id: ?[]const u8,
) ![]CompletionNotice {
return self.takeCompletionNoticesFiltered(allocator, .{
.origin_channel = origin_channel,
.origin_account_id = origin_account_id,
});
}
const CompletionNoticeFilter = struct {
session_key: ?[]const u8 = null,
origin_channel: ?[]const u8 = null,
origin_account_id: ?[]const u8 = null,
};
fn taskMatchesNoticeFilter(state: *const TaskState, filter: CompletionNoticeFilter) bool {
if (filter.session_key) |expected_session| {
const state_session = state.session_key orelse return false;
if (!std.mem.eql(u8, state_session, expected_session)) return false;
}
if (filter.origin_channel) |expected_channel| {
if (!std.mem.eql(u8, state.origin_channel, expected_channel)) return false;
}
if (filter.origin_account_id) |expected_account| {
const state_account = state.origin_account_id orelse return false;
if (!std.mem.eql(u8, state_account, expected_account)) return false;
}
return true;
}
fn takeCompletionNoticesFiltered(
self: *SubagentManager,
allocator: Allocator,
filter: CompletionNoticeFilter,
) ![]CompletionNotice {
var notices: std.ArrayListUnmanaged(CompletionNotice) = .empty;
errdefer {
for (notices.items) |notice| freeNoticeFields(allocator, notice);
notices.deinit(allocator);
}
self.mutex.lock();
defer self.mutex.unlock();
var it = self.tasks.iterator();
while (it.next()) |entry| {
const task_id = entry.key_ptr.*;
const state = entry.value_ptr.*;
if (state.status == .running or state.notified) continue;
if (!taskMatchesNoticeFilter(state, filter)) continue;
const content = formatTaskCompletionContent(allocator, state.label, state.result, state.error_msg) catch continue;
const origin_channel_dup = allocator.dupe(u8, state.origin_channel) catch {
allocator.free(content);
continue;
};
const origin_chat_dup = allocator.dupe(u8, state.origin_chat_id) catch {
allocator.free(content);
allocator.free(origin_channel_dup);
continue;
};
const origin_account_dup: ?[]u8 = if (state.origin_account_id) |aid|
allocator.dupe(u8, aid) catch {
allocator.free(content);
allocator.free(origin_channel_dup);
allocator.free(origin_chat_dup);
continue;
}
else
null;
notices.append(allocator, .{
.task_id = task_id,
.content = content,
.origin_channel = origin_channel_dup,
.origin_chat_id = origin_chat_dup,
.origin_account_id = origin_account_dup,
}) catch {
allocator.free(content);
allocator.free(origin_channel_dup);
allocator.free(origin_chat_dup);
if (origin_account_dup) |aid| allocator.free(aid);
continue;
};
state.notified = true;
}
return notices.toOwnedSlice(allocator);
}
fn freeNoticeFields(allocator: Allocator, notice: CompletionNotice) void {
allocator.free(notice.content);
allocator.free(notice.origin_channel);
allocator.free(notice.origin_chat_id);
if (notice.origin_account_id) |aid| allocator.free(aid);
}
pub fn freeCompletionNotices(allocator: Allocator, notices: []CompletionNotice) void {
for (notices) |notice| freeNoticeFields(allocator, notice);
allocator.free(notices);
}
};
fn resolveWorkspacePath(
allocator: Allocator,
workspace_path: []const u8,
config_path: []const u8,
fallback_workspace: []const u8,
) ?[]const u8 {
if (std_compat.fs.path.isAbsolute(workspace_path)) {
return allocator.dupe(u8, workspace_path) catch null;
}
const normalized_workspace_path = config_mod.normalizeHostPathSeparators(allocator, workspace_path) catch return null;
defer allocator.free(normalized_workspace_path);
const home_dir = std_compat.fs.path.dirname(config_path) orelse fallback_workspace;
return std_compat.fs.path.join(allocator, &.{ home_dir, normalized_workspace_path }) catch null;
}
fn findConfiguredProvider(
configured_providers: []const config_types.ProviderEntry,
provider_name: []const u8,
) ?config_types.ProviderEntry {
for (configured_providers) |entry| {
if (provider_names.providerNamesMatch(entry.name, provider_name)) return entry;
}
return null;
}
fn resolveSubagentProviderApiKey(
configured_provider: ?config_types.ProviderEntry,
explicit_api_key: ?[]const u8,
fallback_api_key: ?[]const u8,
) ?[]const u8 {
if (explicit_api_key) |api_key| return api_key;
if (configured_provider) |entry| {
if (entry.api_key) |api_key| return api_key;
}
return fallback_api_key;
}
fn subagentProviderHolder(
allocator: Allocator,
provider_name: []const u8,
api_key: ?[]const u8,
configured_provider: ?config_types.ProviderEntry,
) providers.ProviderHolder {
return providers.holderFromEntry(allocator, provider_name, api_key, configured_provider);
}
// ── Thread function ─────────────────────────────────────────────
fn subagentThreadFn(ctx: *ThreadContext) void {
defer {
ctx.manager.allocator.free(ctx.task);
ctx.manager.allocator.free(ctx.label);
if (ctx.agent_name) |agent_name| ctx.manager.allocator.free(agent_name);
ctx.manager.allocator.destroy(ctx);
}
if (ctx.manager.observer) |obs| {
if (ctx.trace_id) |tid| {
obs.setTraceId(tid);
}
const name_to_report = ctx.agent_name orelse "default";
const subagent_start_event = observability.ObserverEvent{ .subagent_start = .{
.agent_name = name_to_report,
.task = ctx.task,
} };
obs.recordEvent(&subagent_start_event);
}
// Default prompt differs based on execution mode:
// - tool-loop mode can use restricted tools
// - legacy fallback has no tool access
var system_prompt: []const u8 = if (ctx.manager.task_runner != null)
"You are a background subagent. Complete the assigned task concisely and accurately. Use available tools when they materially improve correctness."
else
"You are a background subagent. Complete the assigned task concisely and accurately. You have no access to interactive tools — focus on reasoning and analysis.";
var default_provider = ctx.manager.default_provider;
var default_model = ctx.manager.default_model;
var temperature: f64 = 0.7;
var explicit_api_key: ?[]const u8 = null;
var effective_workspace = ctx.manager.workspace_dir;
var resolved_workspace: ?[]const u8 = null;
defer if (resolved_workspace) |workspace_dir| ctx.manager.allocator.free(workspace_dir);
if (ctx.agent_name) |agent_name| {
const agent_cfg = ctx.manager.findAgent(agent_name) orelse {
ctx.manager.completeTask(ctx.task_id, null, "UnknownAgent");
return;
};
default_provider = agent_cfg.provider;
default_model = agent_cfg.model;
explicit_api_key = agent_cfg.api_key;
if (agent_cfg.system_prompt) |sp| system_prompt = sp;
if (agent_cfg.temperature) |t| temperature = t;
if (agent_cfg.workspace_path) |workspace_path| {
resolved_workspace = resolveWorkspacePath(
ctx.manager.allocator,
workspace_path,
ctx.manager.config_path,
ctx.manager.workspace_dir,
);
if (resolved_workspace) |workspace_dir| {
config_mod.Config.scaffoldAgentWorkspace(ctx.manager.allocator, workspace_dir) catch {};
effective_workspace = workspace_dir;
}
}
}
const configured_provider = findConfiguredProvider(ctx.manager.configured_providers, default_provider);
const api_key = resolveSubagentProviderApiKey(configured_provider, explicit_api_key, ctx.manager.api_key);
if (ctx.manager.task_runner) |runner| {
const request = TaskRunRequest{
.task = ctx.task,
.system_prompt = system_prompt,
.api_key = api_key,
.default_provider = default_provider,
.default_model = default_model,
.temperature = temperature,
.workspace_dir = effective_workspace,
.allowed_paths = ctx.manager.allowed_paths,
.http_enabled = ctx.manager.http_enabled,
.http_allowed_domains = ctx.manager.http_allowed_domains,
.http_max_response_size = ctx.manager.http_max_response_size,
.http_timeout_secs = ctx.manager.http_timeout_secs,
.tools_config = ctx.manager.tools_config,
.memory_config = ctx.manager.memory_config,
.max_tool_iterations = ctx.manager.config.max_iterations,
.autonomy = ctx.manager.autonomy,
.workspace_only = ctx.manager.workspace_only,
.allowed_commands = ctx.manager.allowed_commands,
.max_actions_per_hour = ctx.manager.max_actions_per_hour,
.require_approval_for_medium_risk = ctx.manager.require_approval_for_medium_risk,
.block_high_risk_commands = ctx.manager.block_high_risk_commands,
.block_medium_risk_commands = ctx.manager.block_medium_risk_commands,
.allow_raw_url_chars = ctx.manager.allow_raw_url_chars,
.configured_providers = ctx.manager.configured_providers,
.observer = ctx.manager.observer,
};
const result = runner(ctx.manager.allocator, request) catch |err| {
ctx.manager.completeTask(ctx.task_id, null, @errorName(err));
return;
};
defer ctx.manager.allocator.free(result);
ctx.manager.completeTask(ctx.task_id, result, null);
return;
}
var cfg_arena = std.heap.ArenaAllocator.init(ctx.manager.allocator);
defer cfg_arena.deinit();
const model = default_model orelse {
ctx.manager.completeTask(ctx.task_id, null, @errorName(error.NoDefaultModel));
return;
};
var holder = subagentProviderHolder(
cfg_arena.allocator(),
default_provider,
api_key,
configured_provider,
);
defer holder.deinit();
const result = holder.provider().chatWithSystem(
cfg_arena.allocator(),
system_prompt,
ctx.task,
model,
temperature,
) catch |err| {
ctx.manager.completeTask(ctx.task_id, null, @errorName(err));
return;
};
ctx.manager.completeTask(ctx.task_id, result, null);
}
// ── Tests ───────────────────────────────────────────────────────
fn waitTaskTerminalStatus(manager: *SubagentManager, task_id: u64) !TaskStatus {
var attempts: usize = 0;
while (attempts < 200) : (attempts += 1) {
const status = manager.getTaskStatus(task_id) orelse return error.TestUnexpectedResult;
if (status != .running) return status;
std_compat.thread.sleep(10 * std.time.ns_per_ms);
}
return error.TestUnexpectedResult;
}
test "subagent provider api key prefers explicit then configured then fallback" {
const entries = [_]config_types.ProviderEntry{.{
.name = "groq",
.api_key = "configured-key",
}};
const configured = findConfiguredProvider(&entries, "groq");
try std.testing.expect(configured != null);
try std.testing.expectEqualStrings(
"explicit-key",
resolveSubagentProviderApiKey(configured, "explicit-key", "fallback-key").?,
);
try std.testing.expectEqualStrings(
"configured-key",
resolveSubagentProviderApiKey(configured, null, "fallback-key").?,
);
try std.testing.expectEqualStrings(
"fallback-key",
resolveSubagentProviderApiKey(null, null, "fallback-key").?,
);
try std.testing.expect(resolveSubagentProviderApiKey(null, null, null) == null);
}
test "subagent provider holder applies configured provider options" {
const configured = config_types.ProviderEntry{
.name = "custom-local",
.base_url = "http://localhost:4321/v1",
.native_tools = false,
.user_agent = "nullclaw-test",
.api_mode = .responses,
.chat_template_enable_thinking_param = true,
.max_streaming_prompt_bytes = 123,
.extra_body_params = "{\"seed\":1}",
};
var holder = subagentProviderHolder(
std.testing.allocator,
"custom-local",
null,
configured,
);
defer holder.deinit();
switch (holder) {
.compatible => |*provider| {
try std.testing.expectEqualStrings("http://localhost:4321/v1", provider.base_url);
try std.testing.expect(!provider.native_tools);
try std.testing.expectEqualStrings("nullclaw-test", provider.user_agent.?);
try std.testing.expectEqual(providers.compatible.CompatibleApiMode.responses, provider.api_mode);
try std.testing.expect(provider.chat_template_enable_thinking_param);
try std.testing.expectEqual(@as(?usize, 123), provider.max_streaming_prompt_bytes);
try std.testing.expectEqualStrings("{\"seed\":1}", provider.extra_body_params.?);
},
else => return error.TestUnexpectedResult,
}
}
fn testTaskRunnerOk(allocator: Allocator, request: TaskRunRequest) ![]const u8 {
_ = request;
return allocator.dupe(u8, "runner-ok");
}
fn testTaskRunnerWorkspace(allocator: Allocator, request: TaskRunRequest) ![]const u8 {
return allocator.dupe(u8, request.workspace_dir);
}
fn testTaskRunnerWorkspaceAndPrompt(allocator: Allocator, request: TaskRunRequest) ![]const u8 {
return std.fmt.allocPrint(
allocator,
"workspace={s}\nprompt={s}",
.{ request.workspace_dir, request.system_prompt },
);
}
fn testTaskRunnerHttpTimeout(allocator: Allocator, request: TaskRunRequest) ![]const u8 {
return std.fmt.allocPrint(allocator, "{d}", .{request.http_timeout_secs});
}
fn testTaskRunnerFail(_: Allocator, _: TaskRunRequest) ![]const u8 {
return error.TestTaskRunnerFailure;
}
test "SubagentManager init and deinit" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();
try std.testing.expectEqual(@as(u64, 1), mgr.next_id);
try std.testing.expect(mgr.bus == null);
}
test "SubagentConfig defaults" {
const sc = SubagentConfig{};
try std.testing.expectEqual(@as(u32, 15), sc.max_iterations);
try std.testing.expectEqual(@as(u32, 4), sc.max_concurrent);
}
test "TaskStatus enum values" {
try std.testing.expect(@intFromEnum(TaskStatus.running) != @intFromEnum(TaskStatus.completed));
try std.testing.expect(@intFromEnum(TaskStatus.completed) != @intFromEnum(TaskStatus.failed));
}
test "TaskState initial defaults" {
const state = TaskState{
.status = .running,
.label = "test",
.origin_channel = "agent",
.origin_chat_id = "session:1",
.started_at = 0,
};
try std.testing.expect(state.result == null);
try std.testing.expect(state.error_msg == null);
try std.testing.expect(!state.notified);
try std.testing.expect(state.completed_at == null);
try std.testing.expect(state.thread == null);
}
test "SubagentManager getRunningCount empty" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();
try std.testing.expectEqual(@as(u32, 0), mgr.getRunningCount());
}
test "SubagentManager getTaskStatus unknown id" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();
try std.testing.expect(mgr.getTaskStatus(999) == null);
}
test "SubagentManager getTaskResult unknown id" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();
try std.testing.expect(mgr.getTaskResult(999) == null);
}
test "SubagentManager completeTask updates state" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();
// Manually insert a task state to test completeTask
const state = try std.testing.allocator.create(TaskState);
state.* = .{
.status = .running,
.label = try std.testing.allocator.dupe(u8, "test-task"),
.origin_channel = try std.testing.allocator.dupe(u8, "agent"),
.origin_chat_id = try std.testing.allocator.dupe(u8, "session:1"),
.started_at = std_compat.time.milliTimestamp(),
};
try mgr.tasks.put(std.testing.allocator, 1, state);
mgr.completeTask(1, "done!", null);
try std.testing.expectEqual(TaskStatus.completed, mgr.getTaskStatus(1).?);
try std.testing.expectEqualStrings("done!", mgr.getTaskResult(1).?);
}
test "SubagentManager completeTask with error" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();
const state = try std.testing.allocator.create(TaskState);
state.* = .{
.status = .running,
.label = try std.testing.allocator.dupe(u8, "fail-task"),
.origin_channel = try std.testing.allocator.dupe(u8, "agent"),
.origin_chat_id = try std.testing.allocator.dupe(u8, "session:1"),
.started_at = std_compat.time.milliTimestamp(),
};
try mgr.tasks.put(std.testing.allocator, 1, state);
mgr.completeTask(1, null, "timeout");
try std.testing.expectEqual(TaskStatus.failed, mgr.getTaskStatus(1).?);
try std.testing.expect(mgr.getTaskResult(1) == null);
}
test "SubagentManager completeTask routes outbound via bus to origin channel" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var bus = bus_mod.Bus.init();
defer bus.close();
var mgr = SubagentManager.init(std.testing.allocator, &cfg, &bus, .{});
defer mgr.deinit();
const state = try std.testing.allocator.create(TaskState);
state.* = .{
.status = .running,
.label = try std.testing.allocator.dupe(u8, "bus-task"),
.origin_channel = try std.testing.allocator.dupe(u8, "telegram"),
.origin_chat_id = try std.testing.allocator.dupe(u8, "chat-42"),
.origin_account_id = try std.testing.allocator.dupe(u8, "primary"),
.started_at = std_compat.time.milliTimestamp(),
};
try mgr.tasks.put(std.testing.allocator, 1, state);
mgr.completeTask(1, "result text", null);
try std.testing.expectEqual(@as(usize, 1), bus.outboundDepth());
var msg = bus.consumeOutbound() orelse return error.TestUnexpectedResult;
defer msg.deinit(std.testing.allocator);
try std.testing.expectEqualStrings("telegram", msg.channel);
try std.testing.expectEqualStrings("chat-42", msg.chat_id);
try std.testing.expect(msg.account_id != null);
try std.testing.expectEqualStrings("primary", msg.account_id.?);
try std.testing.expect(std.mem.indexOf(u8, msg.content, "bus-task") != null);
}
test "SubagentManager takeCompletionNoticesForSession returns once per task" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();
const state = try std.testing.allocator.create(TaskState);
state.* = .{
.status = .running,
.label = try std.testing.allocator.dupe(u8, "notice-task"),
.origin_channel = try std.testing.allocator.dupe(u8, "cli"),
.origin_chat_id = try std.testing.allocator.dupe(u8, "session:42"),
.session_key = try std.testing.allocator.dupe(u8, "session:42"),
.started_at = std_compat.time.milliTimestamp(),
};
try mgr.tasks.put(std.testing.allocator, 1, state);
mgr.completeTask(1, "done", null);
const notices1 = try mgr.takeCompletionNoticesForSession(std.testing.allocator, "session:42");
defer SubagentManager.freeCompletionNotices(std.testing.allocator, notices1);
try std.testing.expectEqual(@as(usize, 1), notices1.len);
try std.testing.expectEqual(@as(u64, 1), notices1[0].task_id);
try std.testing.expect(std.mem.indexOf(u8, notices1[0].content, "notice-task") != null);
const notices2 = try mgr.takeCompletionNoticesForSession(std.testing.allocator, "session:42");
defer SubagentManager.freeCompletionNotices(std.testing.allocator, notices2);
try std.testing.expectEqual(@as(usize, 0), notices2.len);
}
test "CompletionNotice carries origin channel/chat/account for polling delivery (regression #918)" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();
const state = try std.testing.allocator.create(TaskState);
state.* = .{
.status = .running,
.label = try std.testing.allocator.dupe(u8, "polling-task"),
.origin_channel = try std.testing.allocator.dupe(u8, "telegram"),
.origin_chat_id = try std.testing.allocator.dupe(u8, "987654321"),
.origin_account_id = try std.testing.allocator.dupe(u8, "main"),
.session_key = try std.testing.allocator.dupe(u8, "telegram:987654321"),
.started_at = std_compat.time.milliTimestamp(),
};
try mgr.tasks.put(std.testing.allocator, 1, state);
mgr.completeTask(1, "all done", null);
const notices = try mgr.takeCompletionNoticesForSession(std.testing.allocator, null);
defer SubagentManager.freeCompletionNotices(std.testing.allocator, notices);
try std.testing.expectEqual(@as(usize, 1), notices.len);
try std.testing.expectEqualStrings("telegram", notices[0].origin_channel);
try std.testing.expectEqualStrings("987654321", notices[0].origin_chat_id);
try std.testing.expect(notices[0].origin_account_id != null);
try std.testing.expectEqualStrings("main", notices[0].origin_account_id.?);
try std.testing.expect(std.mem.indexOf(u8, notices[0].content, "polling-task") != null);
}
test "CompletionNotice origin_account_id stays null when task has none" {
const cfg = config_mod.Config{
.workspace_dir = "/tmp/yc",
.config_path = "/tmp/yc/config.json",
.allocator = std.testing.allocator,
};
var mgr = SubagentManager.init(std.testing.allocator, &cfg, null, .{});
defer mgr.deinit();